1. <PROGRAM> ::= **program** <IDENTIFIER> ( <FORMALS> ) **;**  
 <DEFINITIONS>  
 <BODY> **.**  
  
2. <DEFINITIONS> ::= **ε**  
3. | <DEF> <DEFINITIONS>  
  
4. <DEF> ::= **function** <IDENTIFIER> **(** <FORMALS> **) :** <TYPE>  
 <BODY> **;**  
  
5. <FORMALS> ::= **ε**  
6. | <NONEMPTYFORMALS>  
  
7. <NONEMPTYFORMALS> ::= <FORMAL> <NONEMPTYFORMALS’>

8. <NONEMPTYFORMALS’> ::= **ε**

9.| , <NONEMPTYFORMALS>  
  
10. <FORMAL> ::= <IDENTIFIER> **:** <TYPE>  
  
11. <BODY> ::= **begin** <STATEMENT-LIST> **end**  
  
12. <STATEMENT-LIST> ::= <PRINT-STATEMENT> <STATEMENT-LIST>  
13. | **return** <EXPR>  
  
14. <TYPE> ::= **integer**  
15. | **boolean**

16. <EXPR> ::= <SIMPLE-EXPR> <EXPR’>

18. <EXPR’> ::= **<** <SIMPLE-EXPR> <EXPR’>

19. | **=** <SIMPLE-EXPR> <EXPR’>

17. | **ε**

20. <SIMPLE-EXPR> ::= <TERM> <SIMPLE-EXPR’>

22. <SIMPLE-EXPR’> ::= **or** <TERM> <SIMPLE-EXPR’>

23. | **+** <TERM> <SIMPLE-EXPR’>

24. | **-** <TERM> <SIMPLE-EXPR’>

21. | **ε**

25. <TERM> ::= <FACTOR> <TERM’>

27. <TERM’> ::= **and** <FACTOR> <TERM’>

28. | **\*** <FACTOR> <TERM’>

29. | **/** <FACTOR> <TERM’>

26. | **ε**  
  
30. <FACTOR> ::= **if** <EXPR> **then** <EXPR> **else** <EXPR>  
31. | **not** <FACTOR>  
32. | <IDENTIFIER> <FACTOR’>  
33. | <LITERAL>  
34. | **-** <FACTOR>  
35. | **(** <EXPR> **)**

36. <FACTOR’> ::= **ε**  
37. | **(** <ACTUALS> **)**  
  
38. <ACTUALS> ::= **ε**  
39. | <NONEMPTYACTUALS>  
  
40. <NONEMPTYACTUALS> ::= <EXPR> <NONEMPTYACTUALS’>

41.<NONEMPTYACTUALS’> ::= **ε**

42. | **,** <NONEMPTYACTUALS>  
  
43. <LITERAL> ::= <NUMBER>  
44. | <BOOLEAN>  
  
45. <PRINT-STATEMENT> ::= **print (** <EXPR> **)** **;**